On this page:
17.1.1 Implicit Form Bindings
17.1.2 Using #lang s-exp

17.1 Module Languages🔗

当使用详细形式的 module 来编写模块时,新模块名称之后指定的模块路径为该模块提供初始导入。由于初始导入模块甚至决定了模块主体中可用的最基本的绑定(如 require),因此初始导入可以称为 module language(模块语言)。

最常见的 module language 是 racket 或 racket/base,但你可以通过定义一个适当的模块来定义自己的 module language。例如,使用 provide 子形式如 all-from-out、except-out 和 rename-out,你可以从 racket 中添加、删除或重命名绑定,以产生一个 racket 变体的 module language:

+The module Form 介绍了详细形式的 module。

> (module raquet racket
    (provide (except-out (all-from-out racket) lambda)
             (rename-out [lambda function])))
> (module score 'raquet
    (map (function (points) (case points
                             [(0) "love"] [(1) "fifteen"]
                             [(2) "thirty"] [(3) "forty"]))
         (list 0 2)))
> (require 'score)

'("love" "thirty")

17.1.1 Implicit Form Bindings🔗

如果你在定义自己的 module language 时尝试从 racket 中删除太多内容,则生成的模块将不再能正常作为 module language 工作:

> (module just-lambda racket
    (provide lambda))
> (module identity 'just-lambda
    (lambda (x) x))

eval:2:0: module: no #%module-begin binding in the module's

language

  in: (module identity (quote just-lambda) (lambda (x) x))

#%module-begin 形式是一个隐式形式,它包装模块的主体。要作为 module language 使用的模块必须提供它:

> (module just-lambda racket
    (provide lambda #%module-begin))
> (module identity 'just-lambda
    (lambda (x) x))
> (require 'identity)

#<procedure>

racket/base 提供的其他隐式形式包括用于函数调用的 #%app、用于字面量的 #%datum 和用于没有绑定的标识符的 #%top:

> (module just-lambda racket
    (provide lambda #%module-begin
             ; ten needs these, too:
             #%app #%datum))
> (module ten 'just-lambda
    ((lambda (x) x) 10))
> (require 'ten)

10

隐式形式如 #%app 可以在模块中显式使用,但它们的存在主要是为了让模块语言能够限制或更改隐式使用的含义。例如,一个 lambda-calculus module language 可能会将函数限制为单个参数,将函数调用限制为提供单个参数,将模块主体限制为单个表达式,禁止字面量,并将未绑定的标识符视为未解释的符号:

> (module lambda-calculus racket
    (provide (rename-out [1-arg-lambda lambda]
                         [1-arg-app #%app]
                         [1-form-module-begin #%module-begin]
                         [no-literals #%datum]
                         [unbound-as-quoted #%top]))
    (define-syntax-rule (1-arg-lambda (x) expr)
      (lambda (x) expr))
    (define-syntax-rule (1-arg-app e1 e2)
      (#%app e1 e2))
    (define-syntax-rule (1-form-module-begin e)
      (#%module-begin e))
    (define-syntax (no-literals stx)
      (raise-syntax-error #f "no" stx))
    (define-syntax-rule (unbound-as-quoted . id)
      'id))
> (module ok 'lambda-calculus
    ((lambda (x) (x z))
     (lambda (y) y)))
> (require 'ok)

'z

> (module not-ok 'lambda-calculus
    (lambda (x y) x))

eval:4:0: lambda: use does not match pattern: (lambda (x)

expr)

  in: (lambda (x y) x)

> (module not-ok 'lambda-calculus
    (lambda (x) x)
    (lambda (y) (y y)))

eval:5:0: #%module-begin: use does not match pattern:

(#%module-begin e)

  in: (#%module-begin (lambda (x) x) (lambda (y) (y y)))

> (module not-ok 'lambda-calculus
    (lambda (x) (x x x)))

eval:6:0: #%app: use does not match pattern: (#%app e1 e2)

  in: (#%app x x x)

> (module not-ok 'lambda-calculus
    10)

eval:7:0: #%datum: no

  in: (#%datum . 10)

模块语言很少重新定义 #%app、#%datum 和 #%top,但重新定义 #%module-begin 更为常用。例如,当使用模块来构造 HTML 页面描述(其中描述从模块中以 page 名称导出)时,替代的 #%module-begin 可以帮助消除 provide 和 quasiquote 样板代码,如 "html.rkt" 中所示:

"html.rkt"

#lang racket
(require racket/date)
 
(provide (except-out (all-from-out racket)
                     #%module-begin)
         (rename-out [module-begin #%module-begin])
         now)
 
(define-syntax-rule (module-begin expr ...)
  (#%module-begin
   (define page `(html expr ...))
   (provide page)))
 
(define (now)
  (parameterize ([date-display-format 'iso-8601])
    (date->string (seconds->date (current-seconds)))))

使用 "html.rkt" module language,可以描述一个简单的网页,而无需显式定义或导出 page,并且以 quasiquote 模式而非表达式模式开始:

> (module lady-with-the-spinning-head "html.rkt"
    (title "Queen of Diamonds")
    (p "Updated: " ,(now)))

open-input-file: cannot open module file

  module path: #<path:/home/komo/works/racket/pkgs/racket-do

c/scribblings/html.rkt>

  path:

/home/komo/works/racket/pkgs/racket-doc/scribblings/html.rkt

  system error: no such file or directory; rkt_err=3

> (require 'lady-with-the-spinning-head)

require: unknown module

  module name: 'lady-with-the-spinning-head

> page

page: undefined;

 cannot reference an identifier before its definition

  in module: top-level

17.1.2 Using #lang s-exp🔗

在 #lang 层面实现一种语言比声明单个模块更复杂,因为 #lang 允许程序员控制语言的多个不同方面。然而,s-exp 语言充当一种元语言,用于通过 #lang 简写形式使用 module language:

#lang s-exp module-name
form ...

等同于

(module name module-name
  form ...)

其中 name 源自包含 #lang 程序的源文件。名称 s-exp 是 "S-expression" 的缩写,这是 Racket 的 reader 层词法约定的传统名称:括号、标识符、数字、带特定反斜杠转义的双引号字符串等等。

使用 #lang s-exp,之前的 lady-with-the-spinning-head 示例可以更简洁地写成:

#lang s-exp "html.rkt"
 
(title "Queen of Diamonds")
(p "Updated: " ,(now))

在本指南后面的 Defining new #lang Languages 中介绍了如何定义自己的 #lang 语言,但首先我们解释如何编写 Racket 的 reader 层扩展。